# Black box algorithm to find standard generators of J4

	set V 0
lbl SEMISTD
	rand 1
	ord 1 A
	incr V
	if V gt 1000 then timeout
	if A notin 1 2 3 4 5 6 7 8 10 11 12 14 15 16 20 21 22 23 24 &
			28 29 30 31 33 35 37 40 42 43 44 66 then fail
	if A notin 20 40 44 then jmp SEMISTD

	div A 4 B
	pwr B 1 3
	mu 3 3 2

	set X 0
lbl CONJUGATE
	incr X
	if X gt 8000 then timeout
	rand 4
	cjr 3 4
	mu 2 3 5
	ord 5 D
	if D notin 2 3 4 5 6 7 8 10 11 12 14 15 16 20 21 22 23 24 &
			28 29 30 31 33 35 37 40 42 43 44 66 then fail
	if D noteq 37 then jmp CONJUGATE

	mu 5 3 6
	mu 5 6 7

	ord 7 E

	# The (2A,4A,37)-fingerprints are given in:
	# R.A.Wilson. "Standard generators for sporadic simple groups"
	# J. Algebra 184 (1996), no. 2, 505--515.
	# This paper gives the following possibilities for o(xyxyy):
	if E notin 10 16 20 22 29 31 37 44 66 then fail

	if E noteq 10 then jmp CONJUGATE

	oup 2 2 3
