# Black box algorithm to find standard generators of McL

	set F 0
	set G 0
	set V 0
lbl SEMISTD
	rand 1
	ord 1 A
	incr V
	if V gt 1000 then timeout
	if A notin 1 2 3 4 5 6 7 8 9 10 11 12 14 15 30 then fail
	if F eq 0 then
		if A in 2 4 6 8 10 12 14 30 then
			div A 2 B
			pwr B 1 2
			set F 1
		endif
	endif
	if G eq 0 then
		if A in 10 15 30 then
			div A 5 C
			pwr C 1 3
			set G 1
		endif
	endif

	if F eq 0 then jmp SEMISTD
	if G eq 0 then jmp SEMISTD
	
	set X 0
lbl CONJUGATE
	incr X
	if X gt 1000 then timeout
	rand 4
	cjr 3 4
	mu 2 3 5
	ord 5 D
	if D notin 6 7 8 10 11 12 14 15 30 then fail
	if D noteq 11 then jmp CONJUGATE

	mu 5 3 6  # abb
	mu 5 6 7  # ababb
	mu 5 5 8  # abab

	mu 8 7 9
	mu 9 7 10
	mu 10 6 11

	ord 11 E

	if E noteq 7 then jmp CONJUGATE

	oup 2 2 3
