# Black box algorithm to find standard generators of He

	set F 0
	set G 0
	set V 0
lbl SEMISTD
	rand 1
	ord 1 A
	incr V
	if V gt 1000 then timeout
	if A notin  1 2 3 4 5 6 7 8 10 12 14 15 17 21 28 then fail
	if F eq 0 then
		if A in 10 28 then
			div A 2 B
			pwr B 1 2
			set F 1
		endif
	endif
	if G eq 0 then
		if A eq 8 then
			pwr 4 1 3	
			set G 1
		endif
	endif

	if F eq 0 then jmp SEMISTD
	if G eq 0 then jmp SEMISTD
	

	set X 0
lbl ELTORDER7
	incr X
	if X gt 1000 then timeout
	rand 4
	cj 3 4 5
	mu 3 5 6
	ord 6 D
	if D notin 1 2 3 4 5 6 7 8 10 12 15 17 21 then fail
	if D notin 7 21 then jmp ELTORDER7
	div D 7 E
	pwr E 6 7

	set Z 0
lbl CONJUGATE
	incr Z
	if Z gt 1000 then timeout
	rand 8
	cjr 7 8
	mu 2 7 9
	ord 9 E
	if E notin 3 4 6 7 8 10 12 15 17 21 28 then fail
	if E noteq 17 then jmp CONJUGATE

	oup 2 2 7
